pkgname=quakespasm
pkgver=0.93.1
pkgrel=1
pkgdesc="A modern Quake 1 engine. Forked from Fitzquake. Stable version with optional Mission pack desktop files."
arch=('i686' 'x86_64')
url="http://quakespasm.sourceforge.net"
license=('GPL2')
depends=('libvorbis' 'libmad' 'flac' 'opusfile' 'libmikmod' 'sdl2')
conflicts=('quakespasm-svn')
install=$pkgname.install
source=(https://sourceforge.net/projects/quakespasm/files/Source/$pkgname-$pkgver.tgz
        $pkgname.desktop)
sha1sums=('aca08d7bea6085bc7b755fad1e83ef976b542c1e'
          'ce21ed7299b5732953bde6e1d9ed073cb21e5d47')

build() {
	cd "$srcdir/$pkgname-$pkgver/Quake/"
	make \
		DO_USERDIRS=1 \
		USE_SDL2=1 \
		USE_CODEC_FLAC=1 \
		USE_CODEC_OPUS=1 \
		USE_CODEC_MIKMOD=1 \
		USE_CODEC_UMX=1
}

package() {
	cd "$srcdir/$pkgname-$pkgver/Quake/"
	install -Dm755 quakespasm "$pkgdir"/usr/bin/$pkgname

	for i in 16 24 32 48 64 72; do
		install -Dm644 $srcdir/$pkgname-$pkgver/Misc/QuakeSpasm_512.png $pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/quakespasm.png
	done

	install -Dm644 $srcdir/$pkgname.desktop $pkgdir/usr/share/applications/$pkgname.desktop
}