quakespasm-spiked-git/PKGBUILD

_pkgname=quakespasm-spiked
pkgname=${_pkgname}-git
pkgver=0.92.1.r332.gd7f84a92
pkgrel=1
pkgdesc="A modern Quake 1 engine. Forked from Quakespasm. AKA QSS. Git version with optional Mission pack desktop files."
arch=('i686' 'x86_64')
url="http://triptohell.info/moodles/qss/"
license=('GPL2')
depends=('libvorbis' 'libmad' 'flac' 'opusfile' 'libmikmod' 'sdl2')
conflicts=('quakespasm-spiked')
provides=('quakespasm-spiked')
install=$_pkgname.install
source=("${_pkgname}::git+https://github.com/Shpoike/Quakespasm"
        $_pkgname.desktop)
sha1sums=('SKIP'
          '3138e0f57c06e9431d1b030fed0983f5fd7db393')

pkgver() {
	cd "$_pkgname"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$srcdir/$_pkgname/quakespasm/Quake/"
	make \
		DO_USERDIRS=1 \
		USE_SDL2=1 \
		USE_CODEC_FLAC=1 \
		USE_CODEC_OPUS=1 \
		USE_CODEC_MIKMOD=1 \
		USE_CODEC_UMX=1
}

package() {
	cd "$srcdir/$_pkgname/quakespasm/Quake/"
	install -Dm755 quakespasm "$pkgdir"/usr/bin/$_pkgname

	for i in 16 24 32 48 64 72; do
		install -Dm644 $srcdir/$_pkgname/quakespasm/Misc/QuakeSpasm_512.png $pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/$_pkgname.png
	done

	install -Dm644 $srcdir/$_pkgname.desktop $pkgdir/usr/share/applications/$_pkgname.desktop
}