b8e4d582ec
Update the SystemD service file to wait for the multi-user target prior to initiating the application and remove the 'WantedBy' parameter. This makes sure that the application does not start prior to the required user being available. upgpkg: cuberite 1.12b975-1 upgpkg: spigot 1.12.2+b73-1
52 lines
2.7 KiB
Bash
52 lines
2.7 KiB
Bash
# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>
|
|
# Contributer: Philip Abernethy <chais.z3r0@gmail.com>
|
|
# Contributer: sowieso <sowieso@dukun.de>
|
|
|
|
pkgname=minecraft-server
|
|
pkgver=1.12.2
|
|
pkgrel=2
|
|
pkgdesc="Minecraft server unit files, script, and jar"
|
|
arch=('any')
|
|
url="https://minecraft.net/"
|
|
license=('custom')
|
|
depends=('java-runtime-headless=8' 'screen' 'sudo' 'bash' 'awk' 'sed')
|
|
optdepends=("tar: needed in order to create world backups"
|
|
"netcat: required in order to suspend an idle server")
|
|
conflicts=('minecraft-server-systemd' 'minecraft-canary')
|
|
backup=('etc/conf.d/minecraft')
|
|
install="${pkgname}.install"
|
|
source=("https://s3.amazonaws.com/Minecraft.Download/versions/${pkgver}/minecraft_server.${pkgver}.jar"
|
|
"minecraftd-backup.service"
|
|
"minecraftd-backup.timer"
|
|
"minecraftd.service"
|
|
"minecraftd.conf"
|
|
"minecraftd.sh")
|
|
noextract=("minecraft_server.${pkgver}.jar")
|
|
sha512sums=('327196bfb833160ae6fb7d12b7d372d031bc0ffbac3455481c1635b01e00f0d5502d4698fbc4f8e7ee59cc3902d56c41261c45d1f1c8f3972e192631f504a0fc'
|
|
'c8f96bafb0ba3fd8946ac791b09e75cae54dc1a8e02822f91ca70a77a8ba45b253a83c4db30f9cfbf0658a2608b38e6de3d00f1d832ef676f329a78e69eab3e7'
|
|
'19ee3646bfbace353b65c0373594edb654de11c9671f29cebad3b31109f29f94ade1d529d9f409b0989c376bef9b451585b22a1e0ac4295fcc92d9565f808418'
|
|
'0c7d8a0c862490967dc392a425d06e8ac008241c29ba1427af0fa6834e25979c62378445c3384dff8af7fdf1ed612cc70ca10e5244723aa2ceb76594ab17dd8f'
|
|
'73132ec613e05c8ed7ebe4eda2395f1ea0733ffe94ba7e203e06246d5852139bbfb7a9073b2b01891282339a2f85676699cd889cde79d6317066e27fd65b1d67'
|
|
'b83b93a25d312825363eb85dec4b04379e9a3b2caf9faaf6f4958966900ecd2d2d5d8c5ecc25fca711da1dbf162129720bed419492ef8bf9dbb1649a5bdb1656')
|
|
|
|
_game="minecraft"
|
|
_server_root="/srv/minecraft"
|
|
|
|
package() {
|
|
install -Dm644 ${_game}d.conf "${pkgdir}/etc/conf.d/${_game}"
|
|
install -Dm755 ${_game}d.sh "${pkgdir}/usr/bin/${_game}d"
|
|
install -Dm644 ${_game}d.service "${pkgdir}/usr/lib/systemd/system/${_game}d.service"
|
|
install -Dm644 ${_game}d-backup.service "${pkgdir}/usr/lib/systemd/system/${_game}d-backup.service"
|
|
install -Dm644 ${_game}d-backup.timer "${pkgdir}/usr/lib/systemd/system/${_game}d-backup.timer"
|
|
install -Dm644 ${_game}_server.${pkgver}.jar "${pkgdir}${_server_root}/${_game}_server.${pkgver}.jar"
|
|
ln -s "${_game}_server.${pkgver}.jar" "${pkgdir}${_server_root}/${_game}_server.jar"
|
|
|
|
# Link the log files
|
|
mkdir -p "${pkgdir}/var/log/"
|
|
install -dm2755 "${pkgdir}/${_server_root}/logs"
|
|
ln -s "${_server_root}/logs" "${pkgdir}/var/log/${_game}"
|
|
|
|
# Give the group write permissions and set user or group ID on execution
|
|
chmod g+ws "${pkgdir}${_server_root}"
|
|
}
|