82a539adb8
* invoke SESSION_NAME when setting IDLE_SESSION_NAME * make the destination of the game command dump configurable * surpress error messages when sourcing since some variables might be set to read-only
52 lines
2.1 KiB
Bash
52 lines
2.1 KiB
Bash
# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>
|
|
# Contributer: Philip Abernethy <chais.z3r0@gmail.com>
|
|
# Contributer: sowieso <sowieso@dukun.de>
|
|
|
|
pkgname=minecraft-server
|
|
pkgver=1.10.2
|
|
pkgrel=3
|
|
pkgdesc="Minecraft server unit files, script, and jar"
|
|
arch=('any')
|
|
url="http://minecraft.net/"
|
|
license=('custom')
|
|
depends=('java-runtime-headless' 'screen' 'sudo' 'bash' 'awk' 'sed')
|
|
optdepends=("tar: needed in order to create world backups"
|
|
"netcat: required in order to suspend an idle server")
|
|
conflicts=('minecraft-server-systemd' 'minecraft-canary')
|
|
backup=('etc/conf.d/minecraft')
|
|
install="${pkgname}.install"
|
|
source=("https://s3.amazonaws.com/Minecraft.Download/versions/${pkgver}/minecraft_server.${pkgver}.jar"
|
|
"minecraftd-backup.service"
|
|
"minecraftd-backup.timer"
|
|
"minecraftd.service"
|
|
"minecraftd.conf"
|
|
"minecraftd.sh")
|
|
noextract=("minecraft_server.${pkgver}.jar")
|
|
md5sums=('41c4e081defd80b09cb0391c894c2f3c'
|
|
'b786935d6517d46fe0944377daba32b8'
|
|
'fef6fadd0739ae03ff71ba61025be207'
|
|
'afb84ad0316af0aca421b36eaa2bbd90'
|
|
'025712e71efa4e21f625bddff28a2f15'
|
|
'1d7efd1c778c7866dcfe9628df847e58')
|
|
|
|
_game="minecraft"
|
|
_server_root="/srv/minecraft"
|
|
|
|
package() {
|
|
install -Dm644 ${_game}d.conf "${pkgdir}/etc/conf.d/${_game}"
|
|
install -Dm755 ${_game}d.sh "${pkgdir}/usr/bin/${_game}d"
|
|
install -Dm644 ${_game}d.service "${pkgdir}/usr/lib/systemd/system/${_game}d.service"
|
|
install -Dm644 ${_game}d-backup.service "${pkgdir}/usr/lib/systemd/system/${_game}d-backup.service"
|
|
install -Dm644 ${_game}d-backup.timer "${pkgdir}/usr/lib/systemd/system/${_game}d-backup.timer"
|
|
install -Dm644 ${_game}_server.${pkgver}.jar "${pkgdir}${_server_root}/${_game}_server.${pkgver}.jar"
|
|
ln -s "${_game}_server.${pkgver}.jar" "${pkgdir}${_server_root}/${_game}_server.jar"
|
|
|
|
# Link the log files
|
|
mkdir -p "${pkgdir}/var/log/"
|
|
install -dm2755 "${pkgdir}/${_server_root}/logs"
|
|
ln -s "${_server_root}/logs" "${pkgdir}/var/log/${_game}"
|
|
|
|
# Give the group write permissions and set user or group ID on execution
|
|
chmod g+ws "${pkgdir}${_server_root}"
|
|
}
|