alpine-git/PKGBUILD

# Maintainer: Yardena Cohen <yardenack at gmail dot com>

_pkgname=alpine
pkgname=$_pkgname-git
pkgver=2.21.99999.373.fe5ffaf
pkgrel=1
pkgdesc="Fork of the PINE mail client (git)"
arch=('i686' 'x86_64')
url='http://alpine.x10host.com/'
license=('APACHE')
depends=('gettext' 'krb5' 'libldap' 'pam')
makedepends=('git')
provides=('alpine' 'pine' 're-alpine')
conflicts=('alpine' 'pine' 're-alpine')
replaces=('alpine' 'pine' 're-alpine')
source=("git+http://repo.or.cz/${_pkgname}.git")
sha512sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgname}"

	# we recently went
	# from 2.21.204.5117359
	# to   2.21.1.209.a9d7a00
	# which rightfully confused pacman's version ordering
	# so let's add a .0 to versions with only one dot
	_ver=$(cat VERSION)
	[[ "$_ver" =~ ^[^\.]+\.[^\.]+\..*$ ]] || _ver=$_ver.0

	_ver="${_ver}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
	printf "%s" "${_ver//-/.}"
}
build() {
	cd "${srcdir}/${_pkgname}"
	LIBS="-lpam -lkrb5 -lcrypto -lssl -ltcl" \
		./configure \
			--prefix=/usr \
			--with-passfile=.pine-passfile \
			--with-system-pinerc=/etc/${pkgname}.d/pine.conf \
			--without-tcl \
			--disable-shared \
			--with-system-fixed-pinerc=/etc/${pkgname}.d/pine.conf.fixed
	make
}
package() {
	cd "${srcdir}/${_pkgname}"
	make DESTDIR="${pkgdir}" install
}