super-coop/source/ai_fight.qc

// ai_fight.qc: monster attack functions

/*

A monster is in fight mode if it thinks it can effectively attack its
enemy.

When it decides it can't attack, it goes into hunt mode.

*/

//=============================================================================

/*
===========
check_attack

The player is in view, so decide to move or launch an attack
Returns FALSE if movement should continue
============
*/
float() check_attack = {
	vector spot1, spot2;
	entity targ;
	float chance;

	targ = self.enemy;

	// see if any entities are in the way of the shot
	spot1 = self.origin + self.view_ofs;
	spot2 = targ.origin + targ.view_ofs;

	trace_line(spot1, spot2, FALSE, self);

	if(trace_ent != targ) {
		return FALSE; // don't have a clear shot
	}

	if(trace_inopen && trace_inwater) {
		return FALSE; // sight line crossed contents
	}

	if(enemy_range == RANGE_MELEE) {
		// melee attack
		if(self.th_melee) {
			if(self.classname == "monster_knight") {
				knight_attack();
			} else {
				self.th_melee();
			}
			return TRUE;
		}
	}

	// missile attack
	if(!self.th_missile) {
		return FALSE;
	}

	if(time < self.attack_finished) {
		return FALSE;
	}

	if(enemy_range == RANGE_FAR) {
		return FALSE;
	}

	if(enemy_range == RANGE_MELEE) {
		chance = 0.9;
		self.attack_finished = 0;
	} else if(enemy_range == RANGE_NEAR) {
		if(self.th_melee) {
			chance = 0.2;
		} else {
			chance = 0.4;
		}
	} else if(enemy_range == RANGE_MID) {
		if(self.th_melee) {
			chance = 0.05;
		} else {
			chance = 0.1;
		}
	} else {
		chance = 0;
	}

	if(random() < chance) {
		self.th_missile();
		sub_attack_finished(2 * random());
		return TRUE;
	}

	return FALSE;
};

/*
=============
ai_face

Stay facing the enemy
=============
*/
void() ai_face = {
	self.ideal_yaw = vec_yaw(self.enemy.origin - self.origin);
	change_yaw();
};

/*
=============
ai_charge

The monster is in a melee attack, so get as close as possible to .enemy
=============
*/
void(float d) ai_charge = {
	ai_face();
	move_to_goal(d); // done in C code...
};

void() ai_charge_side = {
	vector dtemp;
	float heading;

	// aim to the left of the enemy for a flyby

	self.ideal_yaw = vec_yaw(self.enemy.origin - self.origin);
	change_yaw();

	make_vectors(self.angles);
	dtemp = self.enemy.origin - 30 * v_right;
	heading = vec_yaw(dtemp - self.origin);

	walk_move(heading, 20);
};

/*
=============
ai_melee

=============
*/
void() ai_melee = {
	vector delta;
	float ldmg;

	if(!self.enemy) {
		return; // removed before stroke
	}

	delta = self.enemy.origin - self.origin;

	if(vec_len(delta) > 60) {
		return;
	}

	ldmg = (random() + random() + random()) * 3;
	ent_damage(self.enemy, self, self, ldmg);
};

void() ai_melee_side = {
	vector delta;
	float ldmg;

	if(!self.enemy) {
		return; // removed before stroke
	}

	ai_charge_side();

	delta = self.enemy.origin - self.origin;

	if(vec_len(delta) > 60) {
		return;
	}
	if(!ent_can_damage(self.enemy, self)) {
		return;
	}
	ldmg = (random() + random() + random()) * 3;
	ent_damage(self.enemy, self, self, ldmg);
};