#!/usr/bin/env fish

function show-colors -d "Displays all of the terminal colors"
	# hashmaps? what are those!? :D - fish
	set name0  regular
	set name1  bold
	set name2  faint
	set name3  italic
	set name4  underline
	set name5  blink
	set name6  blink2
	set name7  reverse
	set name8  conceal
	set name9  strike
	set name11 font1
	set name12 font2
	set name13 font3
	set name14 font4
	set name15 font5
	set name16 font6
	set name17 font7
	set name18 font8
	set name19 font9
	set name20 fraktur
	set name21 doubleline
	set name51 framed
	set name52 encircled
	set name53 overlined
	set name60 irsline;
	set name61 idoubleline
	set name62 ilsline
	set name63 ioverline2
	set name64 istress

	echo "Terminal modes"
	for mode in (seq 0 9) (seq 11 21) (seq 51 53) (seq 60 64)
		set name name$mode
		printf "Mode %2d: " $mode
		for bg in 49 (seq 40 47)
			echo -n \e"[$mode;"$bg"mlorem"
		end
		echo \e"[0m" \($$name\)
	end
	echo

	echo "4 bit color"
	for bg in 49 (seq 40 47)
		for fg in 39 (seq 30 37)
			echo -n \e"[$mode;$bg;"$fg"m$mode;$bg;$fg"
		end
		echo \e"[0m"
	end
	echo

	echo "8 bit color"
	for fg in (seq 0 15)
		echo -n \e"[48;5;"$fg"m    "
	end
	echo \e"[0m"

	for fg in (seq 232 255)
		echo -n \e"[48;5;"$fg"m   "
	end
	echo \e"[0m"

	for fg in (seq 16 231)
		echo -n \e"[48;5;"$fg"m  "
		test (math \( $fg - 15 \) % 36) -eq 0
		and echo \e"[0m"
	end
	echo \e"[0m"

	set roygcbvp "242;119;119" "242;160;119" "242;217;119" "137;242;119" \
	             "119;234;242" "119;123;242" "180;119;242" "242;119;236"

	set flag "91;207;250" "245;171;185" "255;255;255"

	echo "24 bit color"
	for fg in $roygcbvp
		echo -n \e"[48;2;"$fg"m          "
	end
	echo \e"[0m"

	for fg in 1 2 3 2 1
		echo -n \e"[48;2;"$flag[$fg]"m                "
	end
	echo \e"[0m"
end

## EOF