if status is-interactive
   and not status is-login
   and test -z "$TMUX"

   exec tmux new-session
end

function fish_prompt
   echo (set_color purple)"$hostname% "
end

function fish_right_prompt
   echo (set_color green)(pwd)
end

function fish_greeting
   echo "Word of the moment: "(shuf -n1 /usr/share/dict/words) |
      awk -f ~/src/scripts/mid.awk col=$COLUMNS
end

function rebuild
   $HOME/src/scripts/rebuild.rkt $argv
end

function cheat.sh -d 'Grabs a sheet from cheat.sh' -a arg
   curl cheat.sh/$arg
end

complete -c cheat.sh -xa '(curl -s cheat.sh/:list)'

function ql -d 'Changes directory to a quicklink' -a name
   if not set -q quicklink_$name name
      echo (set_color red)"error: no quicklink named $name"(set_color normal)
      return
   end

   set name quicklink_$name

   cd $$name
end

function ql-r -w ql -d 'Removes a quicklink' -a name
   if not set -q name
      echo (set_color red)"error: not enough arguments"(set_color normal)
      return
   end

   set -Ue quicklink_$name
end

function ql-s -d 'Saves the working directory as a quicklink' -a name
   if not set -q name
      echo (set_color red)"error: not enough arguments"(set_color normal)
      return
   end

   set -U quicklink_$name $PWD
end

complete -c ql -xa '(set -U | rg -or \'$1\' \'^quicklink_(.+) \')'

## EOF