scripts/copy-files

#!/usr/bin/env fish

# copy regular files
mkdir -p \
	applications \
	build-system \
	fonts \
	network \
	scripts \
	system \
	themes \
	unused \
	vim \
	virtual-machines

while read f t
	eval set t $t
	cp -r "$t" "$f"
end < files

# copy font configs
function copy-confd -a path out
	find $path/*.conf > $out/conflist

	for f in $path/*.conf
		if not test -L "$f"
			cp "$f" "$out"
		end
	end
end

copy-confd /etc/fonts/conf.d    system/fonts/
copy-confd /etc/X11/xorg.conf.d system/xorg/

# copy vim package names
tree -dL 3 ~/.vim/pack > vim/packages

for repo in ~/.vim/pack/*/*/*
	pushd $repo
	echo -n (basename $PWD)" "
	if test -d .git
		echo "<"(git config --get remote.(git rev-parse --abbrev-ref "master@{upstream}" | sed 's/\(.*\)\/.*/\1/').url)">"
	else
		echo "<no url>"
	end
	popd
end | sort > vim/package_repos

# erase passwords
sed -i 's/password>.*<\//password>password removed<\//g' network/icecast.xml
sed -i 's/password\(\s*\)".*"/password\1"password removed"/g' network/mpd.conf