class VhtFWeapAxe : FWeapAxe replaces FWeapAxe {
	override void beginPlay() {
		super.beginPlay();
		if(vht_faxe_projectile) {
			ammoUse1 = 1;
		}
	}
	action void vhtFAxeAttack() {
		if(!player) return;
		if(vht_faxe_projectile) {
			let wep = player.readyWeapon;
			if(wep.ammo1 && wep.ammo1.amount > 0) {
				a_fireProjectile("VhtAxeMissile");
			}
		}
		a_fAxeAttack();
	}
	states {
	FireGlow:
		FAXE N 4 offset(15, 32);
		FAXE O 3 offset(15, 32);
		FAXE P 2 offset(15, 32);
		FAXE P 1 offset(-5, 70) vhtFAxeAttack;
		FAXE P 2 offset(-25, 90);
		FAXE Q 1 offset(15, 32);
		FAXE Q 2 offset(10, 54);
		FAXE Q 7 offset(10, 150);
		FAXE A 1 offset(0, 60) a_reFire;
		FAXE A 1 offset(0, 52);
		FAXE A 1 offset(0, 44);
		FAXE A 1 offset(0, 36);
		FAXE A 1;
		goto ReadyGlow;
	}
}

class VhtMWeapWand : MWeapWand replaces MWeapWand {
	states {
	Fire:
		MWND A 0 a_setTics(6 - clamp(vht_mwand_speed, 0, 6));
		MWND B 0 bright offset(0, 48) {
			a_setTics(6 - clamp(vht_mwand_speed, 0, 6));
			a_fireProjectile("MageWandMissile");
		}
		MWND A 3 offset(0, 40);
		MWND A 3 offset(0, 36) a_reFire;
		goto Ready;
	}
}