// ai.qc: monster AI functions

float(entity enemy) enemy_is_gone = {
	return enemy.health <= 0 || enemy.flags & FL_NOTARGET;
};

//
// when a monster becomes angry at a player, that monster will be used
// as the sight target the next frame so that monsters near that one
// will wake up even if they wouldn't have noticed the player
//
float(float v) angle_mod = {
	while(v >= 360) {
		v = v - 360;
	}
	while(v < 0) {
		v = v + 360;
	}
	return v;
};

/*
==============================================================================

MOVETARGET CODE

The angle of the movetarget effects standing and bowing direction, but has no effect on movement, which allways heads to the next target.

targetname
must be present. The name of this movetarget.

target
the next spot to move to. If not present, stop here for good.

pausetime
The number of seconds to spend standing or bowing for path_stand or path_bow

==============================================================================
*/

/*
=============
t_movetarget

Something has bumped into a movetarget. If it is a monster
moving towards it, change the next destination and continue.
==============
*/
void() t_movetarget = {
	entity temp;

	if(other.movetarget != self) {
		return;
	}

	if(other.enemy) {
		return; // fighting, not following a path
	}

	temp = self;
	self = other;
	other = temp;

	if(self.classname == "monster_ogre") {
		sound(self, CHAN_VOICE, "ogre/ogdrag.wav", 1, ATTN_IDLE); // play chainsaw drag sound
	}

	self.goalentity = self.movetarget = find(world, targetname, other.target);
	self.ideal_yaw = vec_yaw(self.goalentity.origin - self.origin);
	if(!self.movetarget) {
		self.pausetime = time + 999999;
		self.th_stand();
		return;
	}
};

void() movetarget_f = {
	if(!self.targetname) {
		error_obj("monster_movetarget: no targetname");
	}

	self.solid = SOLID_TRIGGER;
	self.touch = t_movetarget;
	set_size(self, '-8 -8 -8', '8 8 8');

};

/*QUAKED path_corner(0.5 0.3 0) (-8 -8 -8) (8 8 8)
Monsters will continue walking towards the next target corner.
*/
void() path_corner = {
	movetarget_f();
};


//============================================================================

void() hunt_target = {
	self.goalentity = self.enemy;
	self.think = self.th_run;
	self.ideal_yaw = vec_yaw(self.enemy.origin - self.origin);
	self.nextthink = time + 0.1;
	sub_attack_finished(1); // wait a while before first attack
};

void() sight_sound = {
	string snd;

	switch(self.classname) {
		case "monster_enforcer":
			switch(rint(random() * 3)) {
				case 0: snd = "enforcer/sight3.wav"; break;
				case 1: snd = "enforcer/sight1.wav"; break;
				case 2: snd = "enforcer/sight2.wav"; break;
				case 3: snd = "enforcer/sight4.wav"; break;
			}
			break;
		case "monster_army":        snd = "soldier/sight1.wav";  break;
		case "monster_demon1":      snd = "demon/sight2.wav";    break;
		case "monster_dog":         snd = "dog/dsight.wav";      break;
		case "monster_hell_knight": snd = "hknight/sight1.wav";  break;
		case "monster_knight":      snd = "knight/ksight.wav";   break;
		case "monster_ogre":        snd = "ogre/ogwake.wav";     break;
		case "monster_shalrath":    snd = "shalrath/sight.wav";  break;
		case "monster_shambler":    snd = "shambler/ssight.wav"; break;
		case "monster_tarbaby":     snd = "blob/sight1.wav";     break;
		case "monster_wizard":      snd = "wizard/wsight.wav";   break;
		case "monster_zombie":      snd = "zombie/z_idle.wav";   break;
	}

	sound(self, CHAN_VOICE, snd, 1, ATTN_NORM);
};

void() found_target = {
	if(self.enemy.classname == "player") {
		// let other monsters see this monster for a while
		sight_entity = self;
		sight_entity_time = time;
	}

	self.show_hostile = time + 1; // wake up other monsters

	sight_sound();
	hunt_target();
};

/*
===========
find_target

Self is currently not attacking anything, so try to find a target

Returns TRUE if an enemy was sighted

When a player fires a missile, the point of impact becomes a fakeplayer so
that monsters that see the impact will respond as if they had seen the
player.

To avoid spending too much time, only a single client(or fakeclient) is
checked each frame. This means multi player games will have slightly
slower noticing monsters.
============
*/
float() find_target = {
	entity client;
	float r;

	// if the first spawnflag bit is set, the monster will only wake up on
	// really seeing the player, not another monster getting angry

	// spawnflags & 3 is a big hack, because zombie crucified used the first
	// spawn flag prior to the ambush flag, and I forgot about it, so the second
	// spawn flag works as well
	if(sight_entity_time >= time - 0.1 && !(self.spawnflags & 3)) {
		client = sight_entity;
		if(client.enemy == self.enemy) {
			return FALSE;
		}
	} else {
		client = check_client();
		if(!client) {
			return FALSE; // current check entity isn't in PVS
		}
	}

	if(client == self.enemy ||
	   client.flags & FL_NOTARGET ||
	   client.items & IT_INVISIBILITY) {
		return FALSE;
	}

	r = range(client);
	if(r == RANGE_FAR) {
		return FALSE;
	}

	if(!visible(client)) {
		return FALSE;
	}

	if(r == RANGE_NEAR) {
		if(client.show_hostile < time && !infront(client)) {
			return FALSE;
		}
	} else if(r == RANGE_MID) {
		if(!infront(client)) {
			return FALSE;
		}
	}

	//
	// got one
	//
	self.enemy = client;
	if(self.enemy.classname != "player") {
		self.enemy = self.enemy.enemy;
		if(self.enemy.classname != "player") {
			self.enemy = world;
			return FALSE;
		}
	}

	found_target();

	return TRUE;
};

//=============================================================================

void(float dist) ai_forward = {
	walk_move(self.angles_y, dist);
};

void(float dist) ai_back = {
	walk_move((self.angles_y + 180), dist);
};

/*
=============
ai_pain

stagger back a bit
=============
*/
void(float dist) ai_pain = {
	ai_back(dist);
	/*
		float away;

		away = angle_mod(vec_yaw(self.origin - self.enemy.origin)
		+ 180*(random()- 0.5) );

		walk_move(away, dist);
	*/
};

/*
=============
ai_painforward

stagger back a bit
=============
*/
void(float dist) ai_painforward = {
	walk_move(self.ideal_yaw, dist);
};

/*
=============
ai_walk

The monster is walking it's beat
=============
*/
void(float dist) ai_walk = {
	vector mtemp;

	movedist = dist;

	// check for noticing a player
	if(find_target()) {
		return;
	}

	move_to_goal(dist);
};

/*
=============
ai_stand

The monster is staying in one place for a while, with slight angle turns
=============
*/
void() ai_stand = {
	if(find_target()) {
		return;
	}

	if(time > self.pausetime) {
		self.th_walk();
		return;
	}

	// change angle slightly

};

/*
=============
ai_turn

don't move, but turn towards ideal_yaw
=============
*/
void() ai_turn = {
	if(find_target()) {
		return;
	}

	change_yaw();
};

//=============================================================================

/*
============
facing_ideal

============
*/
float() facing_ideal = {
	float delta;

	delta = angle_mod(self.angles_y - self.ideal_yaw);
	if(delta > 45 && delta < 315) {
		return FALSE;
	}
	return TRUE;
};

//=============================================================================

float() check_any_attack = {
	if(!enemy_vis) {
		return 0;
	}
	switch(self.classname) {
		case "monster_army":     return army_check_attack();
		case "monster_ogre":     return ogre_check_attack();
		case "monster_shambler": return sham_check_attack();
		case "monster_demon1":   return demon_check_attack();
		case "monster_dog":      return dog_check_attack();
		case "monster_wizard":   return wiz_check_attack();
	}
	return check_attack();
};

/*
=============
ai_run_melee

Turn and close until within an angle to launch a melee attack
=============
*/
void() ai_run_melee = {
	self.ideal_yaw = enemy_yaw;
	change_yaw();

	if(facing_ideal()) {
		self.th_melee();
		self.attack_state = AS_STRAIGHT;
	}
};

/*
=============
ai_run_missile

Turn in place until within an angle to launch a missile attack
=============
*/
void() ai_run_missile = {
	self.ideal_yaw = enemy_yaw;
	change_yaw();
	if(facing_ideal()) {
		self.th_missile();
		self.attack_state = AS_STRAIGHT;
	}
};

/*
=============
ai_run_slide

Strafe sideways, but stay at aproximately the same range
=============
*/
void() ai_run_slide = {
	float ofs;

	self.ideal_yaw = enemy_yaw;
	change_yaw();
	if(self.lefty) {
		ofs = 90;
	} else {
		ofs = -90;
	}

	if(walk_move(self.ideal_yaw + ofs, movedist)) {
		return;
	}

	self.lefty = 1 - self.lefty;

	walk_move(self.ideal_yaw - ofs, movedist);
};

/*
=============
ai_run

The monster has an enemy it is trying to kill
=============
*/
void(float dist) ai_run = {
	vector delta;
	float axis;
	float direct, ang_rint, ang_floor, ang_ceil;

	movedist = dist;
	// see if the enemy is dead
	if(enemy_is_gone(self.enemy)) {
		self.enemy = world;
		if(!enemy_is_gone(self.oldenemy)) {
			self.enemy = self.oldenemy;
			hunt_target();
		} else {
			if(self.movetarget) {
				self.th_walk();
			} else {
				self.th_stand();
			}
			return;
		}
	}

	self.show_hostile = time + 1; // wake up other monsters

	// check knowledge of enemy
	enemy_vis = visible(self.enemy);
	if(enemy_vis) {
		self.search_time = time + 5;
	}

	// look for other coop players
	if(coop && self.search_time < time) {
		if(find_target()) {
			return;
		}
	}

	enemy_infront = infront(self.enemy);
	enemy_range = range(self.enemy);
	enemy_yaw = vec_yaw(self.enemy.origin - self.origin);

	if(self.attack_state == AS_MISSILE) {
		//print_dbg("ai_run_missile\n");
		ai_run_missile();
		return;
	}
	if(self.attack_state == AS_MELEE) {
		//print_dbg("ai_run_melee\n");
		ai_run_melee();
		return;
	}

	if(check_any_attack()) {
		return; // beginning an attack
	}

	if(self.attack_state == AS_SLIDING) {
		ai_run_slide();
		return;
	}

	// head straight in
	move_to_goal(dist); // done in C code...
};