actor Lith_CustomInventory : CustomInventory
{
   Inventory.PickupMessage ""
   
   states
   {
   Nope:
      TNT1 A 0
      fail
   }
}

actor Lith_AllMap : Lith_CustomInventory replaces Allmap
{
   Tag "Computer Area Map"
   Inventory.PickupSound "misc/p_pkup"
   
   +COUNTITEM
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      PMAP ABCDCB 6 bright
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_allmap)
      TNT1 A 0 A_GiveInventory("Allmap")
      stop
   }
}

actor Lith_ArmorBonus : Lith_CustomInventory replaces ArmorBonus
{
   Tag "Armor Bonus"
   +COUNTITEM
   
   states
   {
   Spawn:
      BON2 ABCDCB 6
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_armorbonus)
      TNT1 A 0 A_GiveInventory("ArmorBonus")
      stop
   }
}

actor Lith_Backpack : Lith_ScoreItem replaces Backpack
{
   Tag "Backpack"
   Inventory.PickupSound "player/pickup/item"
   
   +COUNTITEM
   
   states
   {
   Spawn:
      BPAK A 0 nodelay A_GiveInventory("Lith_ScoreCount", Score_Backpack)
      BPAK A 0 A_GiveInventory("Lith_ShellAmmo",  AmmoAmt_ShellBackpk)
      BPAK A 0 A_GiveInventory("Lith_RocketAmmo", AmmoAmt_RocketBackpk)
      BPAK A 0 A_GiveInventory("Lith_PlasmaAmmo", AmmoAmt_CellBackpk)
      BPAK A 0 A_GiveInventory("Lith_CannonAmmo", AmmoAmt_CannonBackpk)
      BPAK A -1
      stop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_Discount", 0)
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_backpack)
      goto Super::Pickup
   }
}

actor Lith_Berserk : Lith_CustomInventory replaces Berserk
{
   Tag "Berserk"
   Inventory.PickupSound "misc/p_pkup"
   
   +COUNTITEM
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      PSTR A -1
      stop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_berserk)
      TNT1 A 0 A_GiveInventory("Berserk")
      stop
   }
}

actor Lith_BlueArmor : Lith_CustomInventory replaces BlueArmor
{
   Tag "Blue Armor"
   
   states
   {
   Spawn:
      ARM2 A 6
      ARM2 B 6 bright
      loop
   Pickup:
      TNT1 A 0 A_JumpIf(!CallACS("Lith_CheckArmor", 200), "Nope")
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_bluearmor)
      TNT1 A 0 A_GiveInventory("BlueArmor")
      stop
   }
}

#include "lscripts/Items/BlurSphere.dec"

actor Lith_GreenArmor : Lith_CustomInventory replaces GreenArmor
{
   Tag "Green Armor"
   
   states
   {
   Spawn:
      ARM1 A 6
      ARM1 B 7 bright
      loop
   Pickup:
      TNT1 A 0 A_JumpIf(!CallACS("Lith_CheckArmor", 100), "Nope")
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_greenarmor)
      TNT1 A 0 A_GiveInventory("GreenArmor")
      stop
   }
}

actor Lith_HealthBonus : Lith_CustomInventory replaces HealthBonus
{
   Tag "Health Bonus"
   Inventory.PickupSound "items/healthbonus"
   
   +COUNTITEM
   
   states
   {
   Spawn:
      BON1 ABCDCB 6
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_healthbonus)
      TNT1 A 0 ACS_NamedExecuteWithResult("Lith_GiveHealthBonus", 1)
      stop
   }
}

actor Lith_Infrared : Lith_CustomInventory replaces Infrared
{
   Tag "CB-Goggles"
   Inventory.PickupSound "player/pickup/infrared"
   
   +COUNTITEM
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      PVIS A 6 bright
      PVIS B 6
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_infrared)
      TNT1 A 0 A_GiveInventory("Infrared")
      stop
   }
}

actor Lith_InvulnerabilitySphere : Lith_CustomInventory replaces InvulnerabilitySphere
{
   Tag "Invulnerability"
   Inventory.PickupSound "misc/p_pkup"
   
   +FLOATBOB
   +COUNTITEM
   +INVENTORY.BIGPOWERUP
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      PINV ABCD 6 bright
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_invuln)
      TNT1 A 0 A_GiveInventory("InvulnerabilitySphere")
      stop
   }
}

actor Lith_Medikit : Lith_CustomInventory replaces Medikit
{
   Tag "Medikit"
   
   states
   {
   Spawn:
      MEDI A -1
      stop
   Pickup:
      TNT1 A 0 A_JumpIf(!CallACS("Lith_CheckHealth", 25), "Nope")
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_medikit)
      TNT1 A 0 ACS_NamedExecuteWithResult("Lith_GiveHealth", 25)
      stop
   }
}

actor Lith_Megasphere : Lith_CustomInventory replaces Megasphere
{
   Tag "Tao'chyan"
   Inventory.PickupSound "misc/p_pkup"
   
   +FLOATBOB
   +COUNTITEM
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      MEGA ABCDB 6 bright
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_megasphere)
      TNT1 A 0 A_GiveInventory("BlueArmor")
      TNT1 A 0 ACS_NamedExecuteWithResult("Lith_GiveHealthBonus", 200)
      stop
   }
}

actor Lith_RadSuit : Lith_CustomInventory replaces RadSuit
{
   Tag "Radiation Shielding Suit"
   Inventory.PickupSound "misc/p_pkup"
   
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      SUIT A -1 bright
      stop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_radsuit)
      TNT1 A 0 A_GiveInventory("RadSuit")
      stop
   }
}

actor Lith_SoulSphere : Lith_CustomInventory replaces SoulSphere
{
   Tag "Heart"
   Inventory.PickupSound "misc/p_pkup"
   
   +FLOATBOB
   +COUNTITEM
   +INVENTORY.FANCYPICKUPSOUND
   
   states
   {
   Spawn:
      SOUL ABCDB 6 bright
      loop
   Pickup:
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_soulsphere)
      TNT1 A 0 ACS_NamedExecuteWithResult("Lith_GiveHealthBonus", 100)
      stop
   }
}

actor Lith_Stimpack : Lith_CustomInventory replaces Stimpack
{
   Tag "Stimpack"
   
   states
   {
   Spawn:
      STIM A -1
      stop
   Pickup:
      TNT1 A 0 A_JumpIf(!CallACS("Lith_CheckHealth", 10), "Nope")
      TNT1 A 0 ACS_NamedExecuteAlways("Lith_LogName", 0, msg_stimpack)
      TNT1 A 0 ACS_NamedExecuteWithResult("Lith_GiveHealth", 10)
      stop
   }
}

// EOF